Programming ColdFusion MX, 2nd Edition

Name

XmlNew

Synopsis

                  
                  
                  XmlNew([case_sensitive])

Creates an empty XML document object. An optional Yes/No parameter lets you specify whether XML document elements should maintain their case. The default is No. The following example creates an XML document object and populates it with the contents of a query object:

<cfset MyEmployees = QueryNew("Name,Title")>
<cfset QueryAddRow(MyEmployees, 3)>
<cfset QuerySetCell(MyEmployees, "Name",  "Pere Money", 1)>
<cfset QuerySetCell(MyEmployees, "Title", "President", 1)>
<cfset QuerySetCell(MyEmployees, "Name",  "Aaron Ridge", 2)>
<cfset QuerySetCell(MyEmployees, "Title", "Analyst", 2)>
<cfset QuerySetCell(MyEmployees, "Name",  "Martin Grant", 3)>
<cfset QuerySetCell(MyEmployees, "Title", "Manager", 3)>
   
<cfset EmployeeXml = XMLNew('no')>
<cfset EmployeeXml.XmlRoot = XmlElemNew(EmployeeXml,"company")>
   
<cfloop index="i" from="1" to="#MyEmployees.RecordCount#">
  <cfset EmployeeXml.XmlRoot.XmlChildren[i] = XmlElemNew(EmployeeXml, "employee")>
  <cfset EmployeeXml.XmlRoot.XmlChildren[i].Name = XmlElemNew(EmployeeXml, "name")>
  <cfset EmployeeXml.XmlRoot.XmlChildren[i].Name.XmlText = MyEmployees.name[i]>
  <cfset EmployeeXml.XmlRoot.XmlChildren[i].Title = XmlElemNew(EmployeeXml, "title")>
  <cfset EmployeeXml.XmlRoot.XmlChildren[i].Title.XmlText = MyEmployees.title[i]>
</cfloop>
   
<cfdump var="#EmployeeXml#">